10分钟搞定让你困惑的 Jenkins 环境变量过程详解_其它综合

来源:脚本之家  责任编辑:小易  

前言

Jenkins, DevOps 技术栈的核心之一,CI/CD 离不开编写 Pipeline 脚本,上手 Jenkins ,简单查一下文档,你就应该不会被 agent,stages,step 这类关键词弄懵,也能很快构建出 pipeline 的骨架

但是当向骨架中填充内容的时候,尤其如何利用环境变量(系统内置 | 自定义),多数人都会变得比较混乱,浪费很多时间,本文就帮助大家快速通关环境变量

准备

如果你想一边阅读本文,一边实践,但是没有 Jenkins 服务可用,又想快速尝试,可以应用 Docker 一个命令快速搭建 Jenkins 服务

docker container run --rm -p 8080:8080 -p 50000:50000 --name=jenkins -v $(pwd):/var/jenkins_home jenkins/jenkins

2021 年了,本地没有 Docker 说不过去了,过来瞧瞧 Docker 系列是否入得了你的法眼?

打开浏览器输入:localhost:8080

找到终端的临时密码登陆 安装推荐的依赖 创建新的 Pipeline 类型的 Item 点击左侧 Config,然后在页面底部 Pipeline 部分输入我们接下来写的脚本进行测试就好了

就是这么简单.....

认识 Jenkins 环境变量

Jenkins 环境变量就是通过 env 关键字暴露出来的全局变量,可以在 Jenkins 文件的任何位置使用

其实和你使用的编程语言中的全局变量没有实质差别

查看 Jenkins 系统内置环境变量

Jenkins 在系统内置了很多环境变量方便我们快速使用,查看起来有两种方式:

方式一:

直接在浏览器中访问 ${YOUR_JENKINS_HOST}/env-vars.html 页面就可以,比如 http://localhost:8080/env-vars.html ,每个变量的用途写的都很清楚

方式二

通过执行 printenv shell 命令来获取:

pipeline {
  agent any

  stages {
    stage("Env Variables") {
      steps {
        sh "printenv"
      }
    }
  }
}

直接 Save - Build, 在终端 log 中你会看到相应的环境变量,并且可以快速看到他们当前的值

通常这两种方式可以结合使用

读取环境变量

上面我们说了 env 是环境变量的关键字,但是读取 Jenkins 内置的这些环境变量,env 关键字是可有可无, 但不能没了底裤,都要使用 ${xxx} 包围起来。以 BUILD_NUMBER 这个内置环境变量举例来说明就是这样滴:

如果你在 Jenkins 文件中使用 shell 命令,使用这些内置环境变量甚至可以不用 {}, 来看一下:

pipeline {
  agent any

  stages {
    stage("Read Env Variables") {
      steps {
        echo "带 env 的读取方式:${env.BUILD_NUMBER}"
        echo "不带 env 的读取方式:${BUILD_NUMBER}"
        sh 'echo "shell 中读取方式 $BUILD_NUMBER"'
      }
    }
  }
}

可以看到结果是一样一样滴,不管有几种,记住第一种最稳妥

内置的环境变量虽好,但也不能完全满足我们自定义的 pipeline 的执行逻辑,所以我们也得知道如何定义以及使用自定义环境变量

自定义 Jenkins 环境变量

Jenkins pipeline 分声明式(Declarative)和 脚本式(imperative)写法,相应的环境变量定义方式也略有不同,归纳起来有三种方式:

还是看个实际例子吧:

pipeline {
  agent any

  environment {
    FOO = "bar"
  }

  stages {
    stage("Custom Env Variables") {
      environment {
        NAME = "RGYB"
      }

      steps {
        echo "FOO = ${env.FOO}"
        echo "NAME = ${env.NAME}"

        script {
          env.SCRIPT_VARIABLE = "Thumb Up"
        }

        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}"

        withEnv(["WITH_ENV_VAR=Come On"]) {
          echo "WITH_ENV_VAR = ${env.WITH_ENV_VAR}"
        }
      }
    }
  }
}

来看运行结果:

注意:withEnv(["WITH_ENV_VAR=Come On"]) {} 这里的 = 号两侧不能有空格,必须是 key=value 的形式

一个完整的 pipeline 通常会有很多个 stage,环境变量在不同的 stage 有不同的值是很常见的,知道如何设置以及读取环境变量后,我们还得知道如何重写环境变量

重写 Jenkins 环境变量

Jenkins 让人相对困惑最多的地方就是重写环境变量,但是只要记住下面这三条规则,就可以搞定一切了

withEnv(["WITH_ENV_VAR=Come On"]) {} 内置函数的这种写法,可以重写任意环境变量 定义在 environment {} 的环境变量不能被脚本式定义的环境变量(env.key="value")重写 脚本式环境变量只能重写脚本式环境变量

这三点是硬规则,没涵盖在这 3 点规则之内的也就是被允许的了

三条规则就有点让人头大了,农夫选豆种,举例为证吧

pipeline {
  agent any

  environment {
    FOO = "你当像鸟飞往你的山"
    NAME = "Tan"
  }

  stages {
    stage("Env Variables") {
      environment {
       	// 会重写第 6 行 变量
        NAME = "RGYB" 
       	// 会重写系统内置的环境变量 BUILD_NUMBER
        BUILD_NUMBER = "10" 
      }

      steps {
       	// 应该打印出 "FOO = 你当像鸟飞往你的山"
        echo "FOO = ${env.FOO}" 
       	// 应该打印出 "NAME = RGYB"
        echo "NAME = ${env.NAME}" 
       	// 应该打印出 "BUILD_NUMBER = 10"
        echo "BUILD_NUMBER = ${env.BUILD_NUMBER}" 

        script {
         	// 脚本式创建一个环境变量
          env.SCRIPT_VARIABLE = "1" 
        }
      }
    }

    stage("Override Variables") {
      steps {
        script {
         	// 这里的 FOO 不会被重写,违背 Rule No.2
          env.FOO = "Tara"
         	// SCRIPT_VARIABLE 变量会被重写,符合 Rule No.3
          env.SCRIPT_VARIABLE = "2" 
        }

       	// FOO 在第 37 行重写失败,还会打印出 "FOO = 你当像鸟飞往你的山"
        echo "FOO = ${env.FOO}" 
       	// 会打印出 "SCRIPT_VARIABLE = 2"
        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}" 

       	// FOO 会被重写,符合 Rule No.1
        withEnv(["FOO=Educated"]) { 
         	// 应该打印 "FOO = Educated"
          echo "FOO = ${env.FOO}" 
        }

       	// 道理同上
        withEnv(["BUILD_NUMBER=15"]) {
         	// 应该打印出 "BUILD_NUMBER = 15"
          echo "BUILD_NUMBER = ${env.BUILD_NUMBER}"
        }
      }
    }
  }
}

来验证一下结果吧

看到这,基本的设置应该就没有什么问题了,相信你也发现了,Jenkins 设置环境变量和编程语言的那种设置环境变量还是略有不同的,后者可以将变量赋值为对象,但 Jenkins 就不行,因为在 Jenkins 文件中,所有设置的值都会被当成 String, 难道没办法应用 Boolean 值吗?

Jenkins 中使用 Boolean 值

如果设置一个变量为 false ,Jenkins 就会将其转换为 "false", 如果想使用 Boolean 来做条件判断,必须要调用 toBoolean() 方法做转换

pipeline {
  agent any

  environment {
    IS_BOOLEAN = false
  }

  stages {
    stage("Env Variables") {
      steps {
        script {
         	// Hello 会被打印出来,因为非空字符串都会被认为是 Boolean.True
          if (env.IS_BOOLEAN) {
            echo "Hello"
          }

         	// 真正的 Boolean 比较
          if (env.IS_BOOLEAN.toBoolean() == false) {
            echo "日拱一兵"
          }
         
         	// 真正的 Boolean 
          if (!env.IS_BOOLEAN.toBoolean()) {
            echo "RGYB"
          }
        }
      }
    }
  }
}

来看运行结果:

如果你写过 Pipeline,你一定会知道,写 Pipeline 是离不开写 shell 的,有些时候,需要将 shell 的执行结果赋值给环境变量,Jenkins 也有方法支持

Shell 结果赋值给环境变量

实现这种方式很简单,只需要记住一个格式:sh(script: 'cmd', returnStdout:true)

pipeline {
  agent any

  environment {
   	// 使用 trim() 去掉结果中的空格
    LS_RESULT = "${sh(script:'ls -lah', returnStdout: true).trim()}"
  }

  stages {
    stage("Env Variables") {
      steps {
        echo "LS_RESULT = ${env.LS_RESULT}"
      }
    }
  }
}

总结

关于 Jenkins 环境变量,了解这些基本上就满足绝大多数应用场景了,当再遇到环境变量问题时,可以回过来翻看一下了,有解决的困惑吗?

到此这篇关于10分钟搞定让你困惑的 Jenkins 环境变量的文章就介绍到这了,更多相关Jenkins 环境变量内容请搜索真格学网以前的文章或继续浏览下面的相关文章希望大家以后多多支持真格学网!

您可能感兴趣的文章:docker环境下安装jenkins容器的详细教程Docker环境搭建Jenkins在构建任务时控制台日志出现中文乱码的问题从零搭建docker+jenkins+node.js自动化部署环境的方法在CentOS7上搭建Jenkins+Maven+Git持续集成环境的方法centos下GitLab+Jenkins持续集成环境搭建(安装jenkins)详解Docker下搭建Jenkins构建环境

  • 本文相关:
  • session的存储方式和配置方法介绍
  • 学编程选什么语言好?是php、python还是ruby?
  • ie条件语句 ie hack大全
  • eventstore文件存储设计详解
  • 详解git commit --amend 用法
  • webpack基础教程之名词解释
  • http请求返回415错误码定位解决方法
  • tiobe编程语言排行榜前20的语言入门书籍推荐
  • jenkins部署war包和部署jar包的详细步骤
  • 关于git远程与本地冲突的解决方法
  • ...健身变壮。掌上压竭力只能做20个。想知道刚开始的方法 百度知道
  • 网站首页网页制作脚本下载服务器操作系统网站运营平面设计媒体动画电脑基础硬件教程网络安全javascriptasp.netphp编程ajax相关正则表达式asp编程jsp编程编程10000问css/htmlflex脚本加解密web2.0xml/rss网页编辑器相关技巧安全相关网页播放器其它综合dart首页docker环境下安装jenkins容器的详细教程docker环境搭建jenkins在构建任务时控制台日志出现中文乱码的问题从零搭建docker+jenkins+node.js自动化部署环境的方法在centos7上搭建jenkins+maven+git持续集成环境的方法centos下gitlab+jenkins持续集成环境搭建(安装jenkins)详解docker下搭建jenkins构建环境session的存储方式和配置方法介绍学编程选什么语言好?是php、python还是ruby?ie条件语句 ie hack大全eventstore文件存储设计详解详解git commit --amend 用法webpack基础教程之名词解释tiobe编程语言排行榜前20的语言入门书籍推荐jenkins部署war包和部署jar包的详细步骤关于git远程与本地冲突的解决方法最新idea2020注册码永久激活(激活intellij idea2020永久破解,亲测idea激活码最新获取方法(idea20删除svn三种方法delsvn(windows+最新intellij idea 2020.2永久激intellij idea 2020最新注册码(亲c/s和b/s两种架构的概念、区别和网址(url)支持的最大长度是多少解决使用ide run运行出错package pack/te各种语言常用的一句话判断代码关于git远程与本地冲突的解决方法戏说编码发展史最适合人工智能开发的5种编程语言 附人工做一个优秀程序员应该知道的15件事loongnix安装pycharm community 2020.2.3趁热打铁!httpget与httppost的区别详解jenkins部署war包和部署jar包的详细步骤比较经典技术普及帖 以你刚才在淘宝上买了
    免责声明 - 关于我们 - 联系我们 - 广告联系 - 友情链接 - 帮助中心 - 频道导航
    Copyright © 2017 www.zgxue.com All Rights Reserved